1 REM
2 REM
3 REMSPACEGORN
4 REM
5 REMBY
6 REM
7 REMANTHONYCHIANG
8 REM
9 REM
10 PRINT"[147]     [211]      [208]      [193]      [195]      [197]"
20 PRINT"       [199]       [207]       [210]       [206]"
22 PRINT"    [204][207][193][196][211][212][193][210] IS NOT PUBLIC DOMAIN."
24 PRINT"  [208]LEASE RESPECT THE AUTHOR'S RIGHTS."
30 REM       FORK=1TO3000:NEXT
40 PRINT""SPC(10)"BY [193]NTHONY [195]HIANG"
50 PRINTTAB(7);"[195]HIANG [205][201][206][201]-[193][196][214][197][206][212][213][210][197] #1"
60 FORK=1TO3100:NEXT:PRINTCHR$(14)
70 GOSUB7000
99 RM=1:RB=1:N=16:V=14:DG=2:SW$="SNA"
100 DIMGQ(9,6),NOUN$(30),VERB$(30),MESSAGE$(20),OB$(20),OB(20),FG(20)
105 FORK=1TO11:READOB$(K),OB(K):NEXTK
110 FORK=1TO9:FORK1=1TO6:READGQ(K,K1):NEXTK1:NEXTK
120 FORK=1TOV:READVERB$(K):NEXT:FORK=1TON:READNOUN$(K):NEXT
130 FORK=1TO20:README$(K):FG(K)=1:NEXT:FORK=1TO6:READDI$(K):NEXTK
136 PRINT"[208]RESS [210][197][212][213][210][206] TO START                                  ";
137 GETKK$
138 IFKK$<>CHR$(13)THEN137
140 REM
150 REMMAINSUBROUTINE
160 REM
170 FORPOWER=45TO0STEP-1
180 GOSUB3000:REMCOMMANDS
190 NEXTPO:GOTO4420
200 REM
210 REMROOMSUBROUTINE
220 REM
225 PRINT"[147]"
230 ONRMGOSUB300,400,500,600,700,800,900,1000,1100
240 RB=0:GOTO2000
300 PRINT"[217]OU'RE INSIDE THE SHIP'S DOCK":RETURN
400 PRINT"[217]OU'RE IN THE MAIN HALLWAY":RETURN
500 PRINT"[217]OU'RE IN THE NAVAGATION ROOM":RETURN
600 PRINT"[217]OU'RE IN THE CAPTAIN'S BEDROOM":RETURN
700 PRINT"[217]OU'RE IN THE BATHROOM":RETURN
800 PRINT"[217]OU'RE IN A EMPTY STORAGE ROOM":RETURN
900 PRINT"[217]OU'RE IN THE COMMUNICATIONS ROOM":RETURN
1000 PRINT"[217]OU'RE IN THE END OF THE MAIN HALLWAY":RETURN
1100 PRINT"[217]OU'RE IN THE COMPUTER ROOM":RETURN
2000 REM
2010 REMEXITS&OBJECTS
2020 REM
2030 PRINT:PRINT"[207]BVIOUS [197]XITS:"
2040 FORK=1TO6:IFGQ(RM,K)<>0THENPRINTDI$(K);" ";
2043 NEXTK:PRINT
2045 FORK=1TO11:IFOB(K)=RMTHEN2050
2049 NEXTK:GOTO2080
2050 PRINT:PRINT"[214]ISIBLE [201]TEMS:"
2060 FORK=1TO11:PRINT"";
2062 IFOB(2)=RMANDK=2THENPRINTOB$(2);" ON THE WALL":GOTO2070
2064 IFOB(K)=RMTHENPRINTOB$(K)
2070 NEXTK:PRINT
2080 RETURN
2100 DATA "FRESH BATTERIES",3,"PICTURE OF [215]ILLIAM [211]HATNER",4,"COMBINATION SAFE"
2105 DATA 0,DISINTEGRATION GUN,0
2110 DATA LAZER KEY,5,SAFE'S COMBINATION,0,LOCKED DOOR,8,OPEN DOOR,0,OPEN SAFE
2115 DATA 0,"[194]IG [213]GLY [211]PACE [199]ORN",9,TELECOMPUTER,7
2120 DATA2,0,0,0,0,0
2130 DATA8,1,4,6,3,0
2140 DATA0,0,0,0,0,2
2150 DATA0,5,0,2,0,0
2155 DATA4,0,0,0,0,0
2160 DATA7,0,2,0,0,0
2170 DATA0,6,8,0,0,0
2180 DATA0,2,0,7,0,0
2190 DATA0,8,0,0,0,0
2200 DATA GET,TAK,GOZ,WAL,MOV,USE,UNL,OPE,FIR,SHO,KIL,REA,DRO,THR
2210 DATA BAT,PIC,SAF,GUN,KEY,COM,DOO,NOR,SOU,EAS,WES,UPZ,DOW,TEL,GOR,INV
2220 DATA "[201] DON'T SEE IT HERE"
2230 DATA "[201] CAN'T DO THAT"
2240 DATA "[201]T'S LOCKED"
2250 DATA "[201]T'S OPEN"
2260 DATA "[212]HERE'S SOMETHING BEHIND IT"
2270 DATA "[201]'VE NO BATTERIES"
2280 DATA "[201] CAN'T GO IN THAT DIRECTION"
2290 DATA "[217]OU USE WORD(S) [201] DON'T KNOW"
2300 DATA "[201] DON'T UNDERSTAND YOUR COMMAND"
2310 DATA "[208]LEASE USE TWO WORDS"
2320 DATA "[212]HE SHIP'S POWER IS RUNNING LOW"
2330 DATA "[212]HERE'S NOTHING HERE TO OPEN"
2340 DATA "[212]HE GUN DISINTEGRATES IN YOURHAND!"
2350 DATA "[206]OTHING HAPPENS"
2360 DATA "[217]OU'RE ALREADY CARRYING IT"
2370 DATA "[201]'M NOT CARRYING IT"
2380 DATA "[201] HAVE NO IMMEDIATE USE FOR THAT"
2390 DATA "[193]RE YOU CRAZY!?"
2400 DATA "[212]HERE'S SOMETHING INSIDE"
2410 DATA "[212]HE BATTERIES ARE NOW IN THE GUN"
2420 DATA "[206]ORTH","[211]OUTH","[197]AST","[215]EST","[213]P","[196]OWN"
3000 REM 
3010 REM     COMMANDS
3020 REM 
3030 IF RB = 1 THEN  GOSUB 225
3037 IF POWER < 10 AND PO / 3 =  INT (PO / 3) THEN  PRINT :PRINTME$(11)
3040 PRINT:PRINT"[212]ELL ME WHAT TO DO:";:INPUT"";A$:IFA$="QUIT"THENGOSUB 60000
3042 IFA$="QUIT"THEN3000
3050 IFLEFT$(A$,1)=" "THENA$=RIGHT$(A$,LEN(A$)-1):GOTO3050
3051 IFLEN(A$)>1THEN3060
3052 IFMID$(A$,1,1)="S"THENKN=9:GOTO3600
3053 IFMID$(A$,1,1)="E"THENKN=10:GOTO3600
3054 IFMID$(A$,1,1)="W"THENKN=11:GOTO3600
3055 IFMID$(A$,1,1)="U"THENKN=12:GOTO3600
3056 IFMID$(A$,1,1)="D"THENKN=13:GOTO3600
3057 IFMID$(A$,1,1)="N"THENKN=8:GOTO3600
3058 IFMID$(A$,1,1)="I"THEN3507
3059 GOTO3090
3060 IFLEFT$(A$,4)="LOOK"THENRB=1:GOTO3030
3061 IFMID$(A$,1,3)="INV"ORA$="INVENTORY"THEN3507
3067 IFSW$+LEFT$(A$,2)<>"SNAFU"THEN3069
3068 IFMID$(A$,3,1)=CHR$(67)ANDMID$(A$,4,1)=CHR$(75)THEN3770
3069 IFLEN(A$)<5THEN3090
3070 FORK=1TOLEN(A$):IFMID$(A$,K,1)=" "THEN3100
3080 NEXT
3090 PRINT:PRINTME$(10):GOTO3040
3100 V$=LEFT$(A$,K-1):N$=RIGHT$(A$,LEN(A$)-K)
3112 IFV$="GO"THENV$=V$+"Z"
3117 IFN$="UP"THENN$=N$+"Z"
3120 IFLEN(N$)<3ORLEN(V$)<3THEN3090
3125 V$=LEFT$(V$,3):N$=LEFT$(N$,3)
3130 REM
3140 REMCHECKINGVERBS
3150 REM
3155 IFV$="ATT"ORV$="FIG"THENV$="KIL"
3160 FORKV=1TOV
3170 IFV$=VERB$(KV)THEN3200
3180 NEXTKV:GOTO3590
3190 REM
3200 REMCHECKINGNOUNS
3210 REM
3213 IFN$="LAZ"THENN$="KEY"
3215 IFN$="SPA"THENN$="GOR"
3220 FORKN=1TON
3230 IFN$=NOUN$(KN)THEN3250
3240 NEXTKN:GOTO3590
3250 ONKVGOTO3500,3500,3600,3600,3600,3700,3800,3800,3900,3900,4000,4050,4100
3260 IFKV=14THEN4100
3500 REMGETANDTAKE
3505 IFKN<>16THEN3520
3507 PRINT"[147][217]OU ARE CARRYING:":PRINT
3510 FORK=1TO10:IFOB(K)=-1THENPRINTOB$(K)
3511 NEXT:GOTO3000
3520 IFKN<14ANDKN>7THEN4300
3525 IFKN=3ORKN=14ORKN=7THENPRINTME$(2):GOTO4500
3530 IFOB(KN)=-1THENPRINTME$(15):GOTO4500
3535 IFOB(KN)<>RMTHENPRINTME$(1):GOTO4500
3540 IFNOT(KN=2ANDFG(1)=1ANDRM=4)THEN3543
3541 PRINTME$(5):OB(2)=-1:OB(3)=4:FG(1)=0:FORK=1TO2000:NEXT:GOTO4500
3543 IFFG(2)<>1THEN3555
3544 IFNOT(KN=4ANDOB(1)=-1ORKN=1ANDOB(4)=-1)THEN3555
3545 OB(1)=0:PRINT:PRINTME$(20):FG(2)=0:OB(4)=-1:GOTO4500
3555 IFKN=15THEN4000
3560 OB(KN)=-1:PRINT:PRINT"[207]K!":GOTO4500
3590 PRINT:PRINTME$(8):GOTO3040
3600 REMMOVEGOANDWALK
3605 IFRM=8ANDKN=7THENKN=8
3610 IFKN<8ORKN>13THEN4300
3620 X=KN-7
3630 IFGQ(RM,X)=0THENPRINTME$(7):GOTO4500
3640 RM=GQ(RM,X)
3650 RB=1:GOTO4500
3700 REMUSE
3710 IFKN=14ANDRM=7THEN4050
3720 IFKN<4ORKN>6THEN4300
3740 IFKN=4THEN3900
3750 IFKN=5THENKN=7:GOTO3800
3760 IFKN=6THEN4050
3770 PRINT:PRINT"[201] AM NOT THAT KIND OF GORN!":PO=PO-5:GOTO4500
3800 REMUNLOCKANDOPEN
3803 IFKN=2ANDOB(2)=-1ANDOB(6)=0THENOB(6)=RM:FG(5)=0:GOTO8000
3804 IFKN=2ANDOB(2)<>-1THENPRINTME$(16):GOTO4500
3805 IFKN<>7ANDKN<>3ANDKN<>2THEN3830
3808 IFKN=2ANDFG(5)=0THEN3850
3810 IFNOT(KN=7ANDRM=8ANDOB(5)=-1)THEN3815
3811 GQ(8,1)=9:OB(7)=0:OB(8)=8:PRINT:PRINTME$(4):GOTO4500
3815 IFNOT(KN=3ANDRM=4ANDFG(3)=0)THEN3820
3816 PRINT:PRINTME$(4):PRINT:PRINTME$(19):OB(3)=0:OB(4)=4:OB(9)=4:GOTO4500
3820 IFNOT(KN=7ANDRM<>8ORKN=3ANDRM<>4)THEN3825
3821 PRINT:PRINT"[212]HERE'S NOTHING HERE TO OPEN":GOTO4500
3825 PRINT:PRINTME$(3):GOTO4500
3830 IFKN=14THENPRINT:PRINT"[206]OTHING HERE BUT US SILICON CHIPS":GOTO4500
3840 IFKN>7ORKN=1ORKN=5ORKN=3THEN4300
3850 PRINT:PRINT"[212]HERE'S NOTHING IMPORTANT INSIDE":GOTO4500
3900 REMFIREANDSHOOT
3910 IFKN<>4ANDKN<>15THEN4300
3920 IFOB(4)<>-1THENPRINT:PRINTME$(16):GOTO4500
3930 IFFG(2)=1THENPRINT:PRINTME$(6):GOTO4500
3940 PRINT:PRINTME$(13):OB(4)=0:GOTO4500
4000 REMKILL
4005 IFKN<>15THEN4300
4010 IFRM<>9THENPRINT:PRINT"[212]HE GORN'S NOT HERE":GOTO4500
4015 PRINTME$(18);:INPUTQA$
4018 IFLEFT$(QA$,1)="Y"THEN4030
4020 IFLEFT$(QA$,1)="N"THEN3000
4025 PRINT"[193]NSWER THE QUESTION: ";:GOTO4015
4030 PRINT:PRINT"[212]OO BAD. [212]HE SPACE GORN'S FAVORITE FOOD IS LOONEY UNDER GLASS."
4031 PRINT"[217]OU HAVE JUST BEEN MADE LUNCH."
4032 PRINT"[195]HOMP! [195]HOMP!":GOTO4490
4050 REMREAD
4055 IFKN=6ANDOB(6)=-1THENFG(3)=0:PRINT:PRINT"IT'S 45-21-47 ":GOTO4500
4060 IFKN=6THENPRINT:PRINTME$(16):GOTO4500
4065 IFKN<>14THENPRINT:PRINT"[217]OU DON'T NEED TO READ THAT":GOTO3000
4070 IFRM<>7THENPRINT:PRINTME$(1):GOTO4500
4072 DD=INT(RND(1)*2):IFDD=1THEN4080
4075 PRINT:PRINT"[201]T SAYS:";:PRINT"   [212]HE COMBINATION IS INSIDE  [146]"
4076 PRINTTAB(9);"  [212]HE PICTURE OF [215]ILLIAM     [146]"
4077 PRINTTAB(9);"         [211]HATNER             [146]":GOTO4500
4080 PRINT:PRINT"[201]T SAYS:   [196]ISINTEGRATION ONLY WAY    [146]"
4081 PRINTTAB(9);"    TO KILL SPACE GORN       [146]":GOTO4500
4100 REMDROPTHROW
4110 IFKN>6ORKN=3THEN4300
4120 IFOB(KN)<>-1THENPRINT:PRINTME$(16):GOTO4500
4130 OB(KN)=RM
4140 PRINT:PRINT"[207]K!"
4150 IFOB(4)=9ANDFG(2)=0THEN5000
4160 GOTO4500
4300 PRINT:PRINTME$(9):GOTO3000
4400 REMDEATH
4405 PRINT"[215]ITH ONE MIGHTY SWISH OF HIS TAIL THE"
4406 PRINT"SPACE GORN SLICES YOU IN HALF."
4407 PRINT"    [210]EST IN PEACE.":GOTO4490
4410 REM
4420 PRINT"[212]HE SHIP HAS JUST RUN OUT OF POWER."
4421 PRINT"[209]UICKLY THE TEMPERTURE REACHES THE SUB"
4422 PRINT"ZERO LEVEL. [217]OU ARE FROZEN SOLID AND"
4423 PRINT"THE SPACE GORN EATS YOU LIKE A POPSICLE."
4490 PRINT"           [199][193][205][197][160][207][214][197][210][146]":GOTO6000
4500 IFRM<>9THENDG=2:GOTO4510
4505 DG=DG-1:IFDG=0THEN4400
4510 RETURN
5000 FORK=1TO25:PRINT:NEXTK
5010 PRINT"     [212]HE DISINTEGRATION GUN BOUNCES OFF "
5020 PRINT"THE FLOOR. [212]HE SPACE GORN CATCHES IT AND"
5030 PRINT"EATS IT. [211]UDDENLY, THERE'S A BLINDING   "
5040 PRINT"FLASH!  [212]HE CHEMICALS IN THE GORN'S     "
5050 PRINT"STOMACH MUST HAVE CAUSED THE GUN TO     "
5060 PRINT"EXPLODE.  [215]HEN THE LIGHT DIMS, YOU FIND "
5065 PRINT"A LARGE PILE OF ASHES. [212]HE GUN AND THE  "
5070 PRINT"[199]ORN HAVE DISINTEGRATED.                "
5080 PRINT"[195]ONGRATULATIONS!   [217]OU'VE WON!  "
5085 PRINT
5090 FORK=1TO3:PRINT:NEXT
6000 PRINT"[215]OULD YOU LIKE TO TRY AGAIN? "
6010 GETDE$:IFDE$="Y"THENRUN
6020 IFDE$<>"N"THEN6010
6030 GOTO60040:    REM   [EXIT]                       CLOSE
7000 REM       INSTRUCTIONS
7010 PRINT"[147][211]PACE [199]ORN[146]"
7011 PRINT"     [212]HE YEAR IS 2882, YOU ARE INVES-  "
7012 PRINT"TIGATING A DERELICT STARSHIP, ABANDONED"
7013 PRINT"IN DEEP SPACE. [212]HE MOMENT YOU ENTER,   "
7020 PRINT"[217]OU SMELL THE STENCH ON THE INFAMOUS    [211]PACE [199]ORN!"
7030 PRINT"     [212]HE [211]PACE [199]ORN IS AN 11 FOOT TALL  LIZARD-LIKE CREATURE WITH A ";
7040 PRINT"THICK SCALY SKIN AND A RAZOR SHARP, WHIP-LIKE TAIL."
7050 PRINT"[199]ORNS ARE WELL KNOWN FOR THEIR ENORMOUS APPETITES AND ALSO FOR THEIR";
7060 PRINT" ABILITY TO REGURGITATE STREAMS OF CORROSIVE MOTOR  OIL LIKE SALIVA";
7070 PRINT" TO DIGEST ANY PREY UP TO20 METERS AWAY.  [217]OUR MISSION IS TO FIND";
7080 PRINT"AND DESTROY THE [211]PACE [199]ORN BEFORE THE   SHIP'S POWER RUNS OUT."
7090 PRINT"[199]OOD [204]UCK!"
7100 RETURN
8000 PRINT"[212]HERE'S A COMBINATION INSIDE!":GOTO4500
50000 :
60000 REM   QUIT OPTION
60010 PRINT"[147][193]RE YOU SURE YOU WANT TO QUIT? [[217]/[206]]"
60012 POKE198,0:WAIT198,1:GETPP$:IFPP$<>"Y"ANDPP$<>"N"THEN60010
60020 IFPP$="N"THENRB=1:RETURN
60030 :
60040 REM   LOAD HELLO CONNECT [EXIT]
60050 LOAD"HELLO CONNECT",8